5.2.3.4 節　FACTOR モデル文と付随文

　FACTOR モデル文を用いると、探索的もしくは確証的一次因子分析による因子負荷量や独自性分散を求めることができる。

　この節には、つぎの２つの SAS プログラムのダウンロードコーナーを用意してあります：

1. Thurstone データの LINEQS モデル文による SEM プログラムの例
2. Thurstone データの RAM モデル文による SEM プログラムの例

パス図の例２

つぎの例は、SAS/Stat Software (1997, p.164) の McDonald (1985) が引用した Thurstone データの階層的確証（認）的二次因子分析 (hierarchical second-order confirmatory factor analysis) モデルのパス図である。

図 5.2: Thurston data の McDonald (1985) による SEM のパス図

この図で、facf1、facf2、facf3 は一次的因子で、facf1 は観測変数 senten （sentence 文章）、vocabu（vocabulary 語彙）、sencom（sentence completion 文章完成）に負荷を、facf2 は観測変数 firlet（first letters 第１文字）、 fourlw（four-letter words ４文字語）、suffic（suffices 接尾辞）に負荷を、 facf3 は観測変数　letser（letter series 文字列）、pedigr（pedigrees 語源）、 letgro（letter grouping 文字のグルーピング）に負荷を、それぞれ持つと仮定されている。また、facs は二次的因子で、うえの３つの一次的因子に負荷を持つと仮定されている。

Thurstone データについての lineqs 文による CALIS プログラムを示すと、つぎのようになる。このプログラムは、SAS/STAT Software (1997, pp.164-165) を、図５.２の図にあわせて修正したものである：

*-------------------------------------------------------------------------
*
*  A sas program for applying a CALIS analysis to a correlation matrix of
*  Thurstone reported by McDonald (1985).  This program is a modified
*  version of the program appeared in SAS/STAT Software (1997, p.164).
*
*------------------------------------------------------------------------;
data thurst(type=corr);
  title 'Example of Thurstone''s data reported by McDonald (1985)';
  _type_ ='corr';
  input _name_ $ senten vocabu sencom firlet fourlw suffic letser pedigr
    letgro;

  cards;
senten 1.     .     .     .     .     .     .     .     .
vocabu  .828 1.     .     .     .     .     .     .     .
sencom  .776  .779 1.     .     .     .     .     .     .
firlet  .439  .493  .460 1.     .     .     .     .     .
fourlw  .432  .464  .425  .674 1.     .     .     .     .
suffic  .447  .489  .443  .590  .541 1.     .     .     .
letser  .447  .432  .401  .381  .402  .288 1.     .     .
pedigr  .541  .537  .534  .350  .367  .320  .555 1.     .
letgro  .380  .358  .359  .424  .446  .325  .598  .452 1.
;
proc calis data=thurst method=max edf=212 pestim se;
  title2 'second-order confirmatory FA by LINEQS';
  lineqs
    senten= beta1 facf1 + e1,
    vocabu= beta2 facf1 + e2,
    sencom= beta3 facf1 + e3,
    firlet= beta4 facf2 + e4,
    fourlw= beta5 facf2 + e5,
    suffic= beta6 facf2 + e6,
    letser= beta7 facf3 + e7,
    pedigr= beta8 facf3 + e8,
    letgro= beta9 facf3 + e9,
    facf1 = alph1 facs  + d1,
    facf2 = alph2 facs  + d2,
    facf3 = alph3 facs  + d3;
  std
    facs  = 1.,
    e1-e9 = u11-u19,
    d1-d3 = 3 * 1.;
  bounds
    0. <= u11-u19;
run;

ここで、プログラムの最後の方の bounds 文は、各観測変数の分散をゼロ以上とする制約を指定するもので、MATRIX 文、LINEQS 文、STD 文、COV 文、 RAM 文などで用いることができる。記号 <= 、< 、 >= 、> 、 = は、それぞれ SAS 記号 LE (less than or equal to)、 LT (less than)、GE (greater than or equal to)、GT (greater than)、EQ (equal) でもよい。とりわけ、> または < を用いる場合、ゼロの代わりに 1e-8 (0.00000001) を用いる必要がある。

プログラムのダウンロード・コーナー

sem-Thurstone-lineqs.sas

　つぎに、Thurstone データの RAM 文による CALIS プログラムはつぎのようになる。このデータの RAM 構造のための２つの行列 K _R と Σ_exg のうち、前者を書き下すとつぎのようになる。この場合、観測変数は９個、一次因子（潜在内生変数と見れる）は３個、二次因子（潜在外生変数と見れる）は１個あるので、行列 K_R の次数は (5.20) 式の定義から、１３となる。ユーザは、後者についてもを書き下し、次頁のプログラムでよいことを確かめよ：

(5.35)

*------------------------------------------------------------------------- * * A sas program for applying a CALIS analysis to a correlation matrix of * Thurstone reported by McDonald (1985). * *------------------------------------------------------------------------; data thurst(type=corr); title 'Example of Thurstone''s data reported by McDonald (1985)'; _type_ ='corr'; input _name_ $ senten vocabu sencom firlet fourlw suffic letser pedigr letgro; cards; senten 1. . . . . . . . . vocabu .828 1. . . . . . . . sencom .776 .779 1. . . . . . . firlet .439 .493 .460 1. . . . . . fourlw .432 .464 .425 .674 1. . . . . suffic .447 .489 .443 .590 .541 1. . . . letser .447 .432 .401 .381 .402 .288 1. . . pedigr .541 .537 .534 .350 .367 .320 .555 1. . letgro .380 .358 .359 .424 .446 .325 .598 .452 1. ; proc calis data=thurst method=max edf=212 pestim se; title2 'second-order confirmatory FA by a RAM statement'; ram 1 1 10 .5 beta1, 1 2 10 .5 beta2, 1 3 10 .5 beta3, 1 4 11 .5 beta4, 1 5 11 .5 beta5, 1 6 11 .5 beta6, 1 7 12 .5 beta7, 1 8 12 .5 beta8, 1 9 12 .5 beta9, 1 10 13 .5 alph1, 1 11 13 .5 alph2, 1 12 13 .5 alph3, 2 1 1 3. u11, 2 2 2 3. u12, 2 3 3 3. u13, 2 4 4 3. u14, 2 5 5 3. u15, 2 6 6 3. u16, 2 7 7 3. u17, 2 8 8 3. u18, 2 9 9 3. u19, 2 10 10 1. , 2 11 11 1. , 2 12 12 1. , 2 13 13 1. ; bounds 0. <= u11-u19; run;

プログラムのダウンロード・コーナー

sem-Thurstone-ram.sas

5.2.3.4 節 FACTOR モデル文と付随文

5.2.3.4 節　FACTOR モデル文と付随文