１.１節 カテゴリー変数の度数分布と変数間の関連性の有無の検定
| 1. 度数分布・クロス表用データ例 |
| 2.永久 SAS ファイル作成用 SAS プログラム |
| 3.度数分布・クロス表用 SAS プログラム |
| 4.STATISTICA による度数分布・クロス表作成手順 |
この節には、つぎの２つの SAS プログラムのダウンロードコーナーがあります：
| 1.永久 SAS ファイル用プログラムの例１ |
| 2.度数分布・クロス表用プログラムの例 |
このページは、令和２年５月６日に一部更新しました。
Table 1.1 のデータは、A 大学 514 名の 新入生に対するある年度の永平寺参禅 調査結果の一部を示している。データは各人ごと、通し番号に続く、参禅への動機の 強さ、参禅の有意義さ、座禅時間の長さ、座禅指導の仕方、指導どうり座禅できたか、 参禅の前後での座禅に対するイメージ変化の方向、今後の学生生活の方向づけに 役立ったと思うか、現代の生活に座禅は必要であり今後も座禅の機会を持ちたいか、 食事はどうであったか、睡眠はどうであったか、法話についての意義の評価、 永平寺の雰囲気はよかったか、の１４項目と、それぞれ５段階評定尺度から成る 参禅の前後における座禅に対する態度１０項目（計２０項目）、の合計３４項目 から成る。
1 10 2 3 3 2 2 1 1 4 3 1 4 3 2 22222334333232243332
4 10 2 5 4 2 3 2 1 3 3 3 4 4 2 22232223232222233233
5 10 1 5 4 2 2 3 2 3 4 3 2 4 3 22133323222323334232
6 10 1 4 2 2 2 3 4 4 3 4 2 2 2 22343223222322412222
11 10 1 5 4 2 2 2 5 4 4 3 2 4 3 23232233333333333333
.......................................................
.......................................................
.......................................................
799 1 1 5 2 2 2 2 4 4 4 4 5 4 2 22222222222222222244
813 1 1 5 2 2 2 2 4 4 4 4 5 3 2 32222334222222222222
|
つまり、この調査では、最初の１４項目は定性的（カテゴリー）変数であり 名義尺度（中には評定尺度で間隔尺度と見做せるものもあるが）であり、後半の ２０項目は一応定量的変数で間隔尺度と見做すことができる。 そこで、まず前半の１４項目については、各範ちゅうの度数を数え、後の高度な 分析に備えるとよい。
そのために、ここでは SAS を用いて、まずデータに変数情報をつけて永久SAS ファイルとして保存しておくと便利である。そのためのプログラムの例を示した のが、つぎの表である。紙面の都合上、２つに分けて示す。
*---------------------------------------------------------------------*
| November 18, 2000 |
| sas program--perm_ex1.sas-- |
| example 3 of a sasprogram for making a sas permanent file |
| |
| file name: $HOME/sasprog/multivar/perm_ex1.sas (Unix), or |
| file name: a:￥sasprog￥perm_ex1.sas (Windows) |
| |
*---------------------------------------------------------------------*;
/* In the case when you use a Unix machine,
filename eiheiji '$HOME/educdata/multivar/ds76eihe';
libname sasfile '$HOME/sasset/multivar';
*/
filename eiheiji 'a:￥data￥ds76eihe';
libname sasfile 'a:￥permfile';
options pagesize=66;
data sasfile.eihe;
infile eiheiji;
input noss 5. cat1 3. cat2 2. (cat3-cat14) (4.) +2 (con1-con20) (1.);
label noss='SAMPLE NUMBER'
cat1='DEPARTMENT NUMBER'
cat2='SEX'
cat3='INTENSITY OF MOTIVATION'
cat4='USEFULNESS OF ZEN PRACTICE'
cat5='EVALUATION OF THE TIME FOR ZEN PRACTICE'
cat6='EVALUATION OF ZEN INSTRUCTIONS'
cat7='COULD PRACTICE ZEN AS WAS INSTRUCTED?'
cat8='ZEN IMAGE CHANGE THROUGH ZEN PRACTICE'
cat9='USEFULNESS FOR FUTURE STUDENT LIFE'
cat10='NECESSITY AND HOPE FOR ZEN PRACTICE'
cat11='WERE THE MEALS VOLUMINOUS?'
cat12='COULD YOU SLEEP LAST NIGHT?'
cat13='USEFULNESS OF ZEN LECTURE'
cat14='FEEING ABOUT THE ATMOSPHERE OF EIHEIGI'
con1='ZEN SERVE TO RECOVER OUR MENTAL BALANCE.'
con2='ZEN IS GOOD FOR MENTAL conCENTRATION.'
con3='ZEN IS A GOOD CHANCE TO GAZE AT ONESELF.'
con4='ZEN IS APPROPRIATE FOR conCENTRATION.'
con5='ZEN GIVE A CHANCE TO EXAMINE ONESELF.'
con6='IMPOSSIBLE TO RELIEVE A PERSON BY ZEN.'
con7='ZEN IS MERELY A SELF-conTENTMENT.'
con8='IT IS UNABLE TO GAZE AT ONESELF BY ZEN.'
con9='ZEN IS VERY TIRESOME.'
con10='ZEN IS MERELY A SELF-ABSORPTION.'
con11='ZEN IS GOOD FOR MENTAL HEALTH.'
con12='ZEN GIVE A CHANCE TO EXAMINE ONESELF.'
con13='ZEN IS GOOD FOR MENTAL conCENTRATION.'
con14='ZEN SERVE TO RECOVER OUR MENTAL BALANCE.'
con15='ZEN IS A GOOD CHANCE TO GAZE AT ONESELF.'
con16='INCREDIBLE TO LIKE SUCH A HARD PRACTICE.'
con17='ZEN IS MERELY A SELF-ABSORPTION.'
con18='IMPOSSIBLE TO RELIEVE A PERSON BY ZEN.'
con19='ZEN IS MERELY A SELF-conTENTMENT.'
con20='IT IS UNABLE TO GAZE AT ONESELF BY ZEN.' ;
run;
|
/*
libname library '$HOME/sasset/format';
*/
libname library 'a:￥format';
proc format library=library;
value cat1fmt 1='dept.1' 2='dept.2' 3='dept.3' 4='dept.4' 5='dept.5'
6='dept.6' 7='dept.7' 8='dept.8' 9='dept.9' 10='dept.10';
value cat2fmt 1='male' 2='female';
value cat3fmt 1='very strong' 2='fairly strong' 3='weak'
4='very weak' 5='can not clasify';
value cat4fmt 1='very useful' 2='useful' 3='somewhat useful'
4='do not know' 5='somewhat useless' 6='very useless';
value cat5fmt 1='short' 2='appropriate' 3='long';
value cat6fmt 1='too severe' 2='appropriate' 3='more severely';
value cat7fmt 1='yes' 2='dk' 3='no';
value cat8fmt 1='good to good' 2='good to dk' 3='good to bad'
4='dk to good' 5='dk to dk' 6='dk to bad'
7='bad to good' 8='bad to dk' 9='bad to bad';
value cat9fmt 1='very useful' 2='fairly useful' 3='somewhat useful'
4='dk' 5='not so useful' 6='not useful at all';
value cat10fmt 1='definitely' 2='think so' 3='a bit'
4='dk' 5='rather not' 6='not at all';
value cat11fmt 1='very voluminous' 2='rather voluminous' 3='as usual'
4='not voluminous' 5='not at all';
value cat12fmt 1='yes, sufficient' 2='yes, a little' 3='dk'
4='no, not well' 5='no, not at all';
value cat13fmt 1='very useful' 2='fairly useful' 3='somewhat useful'
4='dk' 5='not so useful' 6='not useful at all';
value cat14fmt 1='very good' 2='good' 3='rather good' 4='no feeling'
5='not so good' 6='not good at all';
run;
proc print data=sasfile.eihe n;
title 'data on the Eiheiji zen practice in 1976';
run;
|
ここでプログラムの後半部を削ると、カテゴリー変数の各コードに対応する カテゴリー名が出力結果に表示できない。しかし、なくてもかまわない。
| perm_ex1.sas |
永久 SAS ファイルが完成すると、後はこれを呼びだしてつぎのような数行の プログラムを書いてやると、カテゴリー変数の各範ちゅうへの度数が出力される。
*-------------------------------------------------------------------* | November 18, 2000 | | sas program--freq_ex1.sas-- | | example 3 of a sasprogram for freq procedure | | | | file name: $HOME/sasprog/multivar/freq_ex1.sas (Unix), or | | file name: a:￥sasprog￥freq_ex1.sas (Windows) | | | *-------------------------------------------------------------------*; /* libname sasfile '$HOME/sasset/multivar'; libname library '$HOME/sasset/format'; */ libname sasfile 'a:￥permfile'; libname library 'a:￥format'; options pagesize=60 ls=80; title 'frequency distribution with format'; proc freq data=sasfile.eihe; tables cat1-cat4; format cat1 cat1fmt. cat2 cat2fmt. cat3 cat3fmt. cat4 cat4fmt.; run; title 'frequency distribution without format'; proc freq data=sasfile.eihe; tables cat1-cat4; run; title 'contingency table with cell-chisquares'; proc freq data=sasfile.eihe; tables cat2*cat6/expected cellchi2 chisq; format cat2 cat2fmt. cat6 cat6fmt.; run; title 'contingency tables with cell-chisquares'; proc freq data=sasfile.eihe; tables (cat1-cat3)*cat4/expected cellchi2 chisq nocol norow; format cat1 cat1fmt. cat2 cat2fmt. cat3 cat3fmt. cat4 cat4fmt.; run; |
| freq_ex1.sas |
STATISTICA により、上記の SAS プログラムで指示したとほぼ同様な結果を得る ための手順を以下に列記する。中心的課題は、cat1-cat4 (STATISTICA 用にはこれら は var2 から var5 が対応）の度数分布表及びヒストグラム、及び cat2 と cat7 のクロス表作成と当該クロス表の２辺数間の関連性の有無の検定である：
|